TITLE, "LCLS: design"

  OPTION, -INTER, -ECHO, WARN
  ASSIGN, PRINT="GUN_SPECT.print"
  ASSIGN, ECHO="GUN_SPECT.echo"

! ==============================================================================
! 20-JUN-2003
! ------------------------------------------------------------------------------

  Ei     := 0.0061   !initial beam energy (GeV)
  EMITXN := 2.80E-06 !normalized horizontal emittance (m)
  EMITYN := 2.80E-06 !normalized vertical emittance (m)
  BLENG  := 0.83E-03 !bunch length (m)
  ESPRD  := 1.00E-03 !energy spread (1)

  TBETX := 13.44    !twiss beta x (m)
  TALFX := 15.00    !twiss alpha x
  TBETY := 13.44    !twiss beta y (m)
  TALFY := 15.00    !twiss alpha y

  TWSS0 : BETA0, ENERGY=Ei, BETX=TBETX, ALFX=TALFX, BETY=TBETY, ALFY=TALFY

! construct input beam matrix

  EMITX := EMITXN/(TWSS0[ENERGY]/EMASS)
  EMITY := EMITYN/(TWSS0[ENERGY]/EMASS)
  TGAMX := (1+TWSS0[ALFX]*TWSS0[ALFX])/TWSS0[BETX]
  TGAMY := (1+TWSS0[ALFY]*TWSS0[ALFY])/TWSS0[BETY]
  SIG11 := EMITX*TWSS0[BETX]
  SIG21 := -EMITX*TWSS0[ALFX]
  SIG22 := EMITX*TGAMX
  SIG33 := EMITY*TWSS0[BETY]
  SIG43 := -EMITY*TWSS0[ALFY]
  SIG44 := EMITY*TGAMY
  C21   := SIG21/SQRT(SIG11*SIG22)
  C43   := SIG43/SQRT(SIG33*SIG44)

  SIG0  : SIGMA0, SIGX=SQRT(SIG11), SIGPX=SQRT(SIG22), R21=C21, &
                  SIGY=SQRT(SIG33), SIGPY=SQRT(SIG44), R43=C43, &
                  SIGT=BLENG,       SIGPT=ESPRD

  BEAM, PARTICLE=ELECTRON, ENERGY=TWSS0[ENERGY], EX=EMITX, EY=EMITY, &
        SIGT=BLENG, SIGE=ESPRD

! conversion factors

  Cb      : CONSTANT=1.0E10/CLIGHT !energy to magnetic rigidity
  GeV2MeV : CONSTANT=1000.0        !GeV to MeV
  in2m    : CONSTANT=0.0254        !inches to meters

! ==============================================================================
! BENDs
! ------------------------------------------------------------------------------

  LB0 := 0.266         !5D7.1 "Z" length (m)
  GB0 := 1.0*in2m      !5D7.1 gap height (m)
  AB0 := 94.818853112106*RADDEG !injection line angle (rad)

  LeffB0 := LB0*AB0/(2*SIN(AB0/2)) !full bend path length (m)
  EI     := 31.151748519378*RADDEG
  VALUE, LeffB0
  
  B00    : SBEN, L=LeffB0, HGAP=GB0/2, ANGLE=AB0, &
                 E1=EI, E2=EI, FINT=0.45, FINTX=0.45

  Q1   : QUAD, L=0.05, K1=0.0, APER=rQ
  D1   : DRIF, L=0.4
  D2   : DRIF, L=0.10
  D3   : DRIF, L=0.15

  GSBL : LINE=(D1,B00,D2,Q1,D3)

  USE, GSBL
  MATCH, BETA0=TWSS0
    VARY, Q1[K1], STEP=1.E-5, LOWER=-350,  UPPER=+350
!    VARY, EI, STEP=1.E-5, LOWER=0,  UPPER=+35*RADDEG
!!   VARY, D2[L], STEP=1.E-5, LOWER=0.15,  UPPER=0.5
!!   VARY, D3[L], STEP=1.E-5, LOWER=0.15,  UPPER=0.6
!    VARY, AB0, STEP=1.E-5
    RMATRIX, #S/#E, RM(1,6)=0.05
!    RMATRIX, #S/#E, RM(1,2)=0, RM(3,4)=0, WEIGHT(1,2)=10, WEIGHT(3,4)=10
    LMDIF
    MIGRAD
  ENDMATCH
  VALUE, EI/RADDEG
  VALUE, Q1[K1]
  VALUE, D2[L]
  VALUE, D3[L]
  VALUE, AB0/RADDEG
  
! ==============================================================================
! COMMANDs
! ------------------------------------------------------------------------------

  SETPLOT, XSIZE=25.4, YSIZE=20.32
  OPTION, ECHO

  ! do fitting
! generate output files and plots (optics)

  USE, GSBL
  PRINT, FULL
  SELECT, OPTICS, FULL
  TWISS, BETA0=TWSS0, SAVE, TAPE="GUN_SPECT_twiss.tape"
  ENVELOPE, SIGMA0=SIG0, SAVE, TAPE="GUN_SPECT_envelope.tape"

  PLOT, TABLE=TWISS, HAXIS=S, VAXIS1=BETX,BETY, VAXIS2=DX, STYLE=100, &
    SPLINE=.F., RANGE=#S/#E, TITLE="Gun Spect."

  STOP