! ==============================================================================
! -- Original A-line based on M. Woodley's deck.
! ------------------------------------------------------------------------------

! ==============================================================================
! dipoles
! ------------------------------------------------------------------------------

! "emergency" bends B1 & B2

  LBB   :=  0.648
  ABB   := -0.436924507458E-2
  KB1B2 :=  0

  B1A : SBEN, L=LBB/2, ANGLE=ABB/2, K1=-KB1B2, E1=0,     FINT=0.5, FINTX=0
  B1B : SBEN, L=LBB/2, ANGLE=ABB/2, K1=-KB1B2, E2=ABB,   FINT=0,   FINTX=0.5
  B2A : SBEN, L=LBB/2, ANGLE=ABB/2, K1=+KB1B2, E1=-ABB,  FINT=0.5, FINTX=0
  B2B : SBEN, L=LBB/2, ANGLE=ABB/2, K1=+KB1B2, E2=2*ABB, FINT=0,   FINTX=0.5

! A-bends

  AARC  := -24*RADDEG !total arc bend angle (24 degrees)
  Nbend := 12         !number of arc bends
  ABA   := AARC/Nbend !arc bend angle

  LBA := 3.024 !present A-line bends
  GBA := 0.06  !Blue Book value

  BA1 : SBEN, L=LBA/2, HGAP=GBA/2, ANGLE=ABA/2, E1=ABA/2, FINT=0.5, FINTX=0
  BA2 : SBEN, L=LBA/2, HGAP=GBA/2, ANGLE=ABA/2, E2=ABA/2, FINT=0, FINTX=0.5

! ==============================================================================
! quadrupoles
! ------------------------------------------------------------------------------

! 50-line

  LQ1 := 0.187342
  LQ2 := 0.324302
  LQ3 := 0.286508

  rQ1 :=  10.325e-3
  rQ2 :=  10.325e-3
  rQ3 :=  10.325e-3

  K50Q :=  0.281785509238 !LCLS04NOV07 value
  KQ1  := -K50Q
  KQ2  :=  K50Q
  KQ3  := -K50Q

  Q1 : QUAD, L=LQ1/2, K1=KQ1, APER=rQ1
  Q2 : QUAD, L=LQ2/2, K1=KQ2, APER=rQ2
  Q3 : QUAD, L=LQ3/2, K1=KQ3, APER=rQ3

! present A-line

  LQ8cm := 2.0
  rQ8cm := 0.08/2
  LQ19  := 2.0
  rQ19  := 0.186/2
  LQ20  := 1.31318
  rQ20  := 8.25*0.0254/2
  LSQ   := 0.55
  rSQ   := 0.08/2

  KQ10 :=  0.040190926401
  KQ11 := -0.037926743862
  KQ19 :=  0.029507959162    !0.032191661707
  KQ20 :=  0.961853807504E-2 !0.20869827928E-2
  KQ27 := -0.06339026
  KSQ  :=  0.0
  KQ28 :=  0.03715726
  KQ30 := -0.03054855
  KQ38 :=  0.03460619

  Q10      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ10
  Q11      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ11
  Q19      : QUAD, L=LQ19/2,  APER=rQ19,  K1=KQ19
  Q20      : QUAD, L=LQ20/2,  APER=rQ20,  K1=KQ20
  Q27      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ27
  Q28      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ28
  "SQ27.5" : QUAD, L=LSQ/2,   APER=rSQ,   K1=KSQ, TILT
  Q30      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ30
  Q38      : QUAD, L=LQ8cm/2, APER=rQ8cm, K1=KQ38

! ------------------------------------------------------------------------------

! SLC FF CCS quadrupole (1.625Q27.3)

  LQFF   := 2*1.17165*0.3048
  rQFF   := 1.625*0.0254/2
  G1Lmax := 450.0 !410 amps
  K1max  := G1Lmax/LQFF/Brho

! ==============================================================================
! energy collimator
! ------------------------------------------------------------------------------

  MSLIT : RCOLL, L=10.2*0.0254 !LI30 movable-jaw collimator (2.75" bore)

! ==============================================================================
! drifts
! ------------------------------------------------------------------------------

! 50-line

  D001   : DRIF, L=0.134786
  D002   : DRIF, L=15.926803
  D003   : DRIF, L=4.179027
  D004   : DRIF, L=0.785775
  "50B1" : DRIF, L=2.264054
  D005   : DRIF, L=8.493548

! present A-line

  D101 : DRIF, L=21.132917
  D102 : DRIF, L=9.12592
  D103 : DRIF, L=69.834638
  D104 : DRIF, L=0.52275
  D105 : DRIF, L=5.5372
  D106 : DRIF, L=0.727
  D107 : DRIF, L=0.7755
  D108 : DRIF, L=3.84839
  D109 : DRIF, L=0.7755
  D110 : DRIF, L=3.84839
  D111 : DRIF, L=0.7755
  D112 : DRIF, L=15.74899
  D113 : DRIF, L=9.0997
  D114 : DRIF, L=5.94572
  D115 : DRIF, L=0.7755
  D116 : DRIF, L=3.84839
  D117 : DRIF, L=0.7755
  D118 : DRIF, L=3.84839
  D119 : DRIF, L=0.7755
  D120 : DRIF, L=1.744768 !1.74477
  D121 : DRIF, L=1.525
  D122 : DRIF, L=1.925
  D123 : DRIF, L=38.1116
  D124 : DRIF, L=21.4778
  D125 : DRIF, L=5.04065
  D126 : DRIF, L=76.23456
  D127 : DRIF, L=92.118

  D002a : DRIF, L=1.745472
  D002b : DRIF, L=0.0184
  D002c : DRIF, L=14.162931
  D126a : DRIF, L=15.322492
  D126b : DRIF, L=9.72325
  D126c : DRIF, L=D126[L]-(D126a[L]+D126b[L])

  LBEND1 := LBA+D107[L]+LBA+D108[L]+LBA+D109[L]+LBA+D110[L]+LBA+D111[L]+LBA
  LBEND2 := LBA+D115[L]+LBA+D116[L]+LBA+D117[L]+LBA+D118[L]+LBA+D119[L]+LBA
  LTOT   := LBEND1+D112[L]+LQ19+D113[L]+LQ20+D114[L]+LBEND2

! ==============================================================================
! coordinate rolls ... bend plane rotated to remove linac slope
! ------------------------------------------------------------------------------

  ROLLON := 1.0

  ROLL1 : SROT, ANGLE= 0.014303845885    * ROLLON
  ROLL2 : SROT, ANGLE=-0.393462907527E-2 * ROLLON
  ROLL3 : SROT, ANGLE=-0.011395368282    * ROLLON

! ==============================================================================
! markers
! ------------------------------------------------------------------------------

  MK29    : MARK !DBMARK29 ... LI30 FV2
  FFTB    : MARK !origin of FFTB Z coordinates
  S100    : MARK !station 100
  MK14    : MARK !DBMARK14 ... entrance to 50B1
  SWIVEL  : MARK
  BETRGT  : MARK
  DIVERGE : MARK
  D10J    : MARK
  D19A    : MARK
  D10H    : MARK
  FLNG    : MARK

  BEGB : MARK
  ENDB : MARK
  WALL : MARK
  ESAW : MARK
  PVOT : MARK
  ESAE : MARK
  BMDE : MARK

! ==============================================================================
! beamlines
! ------------------------------------------------------------------------------
! "50LINE"  : match at end of THF bypass line to ROLL2
! ALINE     : existing beamline, starting at ROLL2 (matched to DXi=DPXi=0)
! S100ALINE : existing beamline, starting at S100
! ------------------------------------------------------------------------------

  BA    : LINE=(BA1,BA2)
  LD002 : LINE=(D002a,FFTB,D002b,S100,D002c)
  LD126 : LINE=(D126a,ESAW,D126b,PVOT,D126c)

  MK29S100  : LINE=(MK29,D001,Q1,Q1,D002a,FFTB,D002b)

  "50LINE" : LINE=(&
    MK29,D001,Q1,Q1,LD002,Q2,Q2,D003,Q3,Q3,D004,MK14,"50B1",D005,SWIVEL)

  ALINE : LINE=(&
    D101,ROLL1,B1A,B1B,D102,B2A,B2B,D103,ROLL2,&
    D104,Q10,Q10,D105,Q11,Q11,D106,&
    BEGB,BA,D107,BA,D108,BA,D109,BA,D110,BA,D111,BA,&
    D112,Q19,Q19,D113,Q20,Q20,D114,&
    BA,D115,BA,D116,BA,D117,BA,D118,BA,D119,BA,ENDB,&
    D120,Q27,Q27,D121,"SQ27.5","SQ27.5",D122,Q28,Q28,&
    D123,Q30,Q30,D124,Q38,Q38,D125,WALL,&
    LD126,ESAE,D127,BMDE)

  BSYALINE : LINE=("50LINE",ALINE)

  S100ALINE : LINE=(S100,D002c,Q2,Q2,D003,Q3,Q3,D004,MK14,&
                   "50B1",D005,SWIVEL,ALINE)

! ------------------------------------------------------------------------------
! End of existing line optics
! ------------------------------------------------------------------------------

  RETURN

! ------------------------------------------------------------------------------
! Start modifications
! ------------------------------------------------------------------------------
! Insert PR10 marker and two ESA focal points EFOC, EFOC2

  KQ30 := -0.028382598446 !to focus at EFOC
  KQ38 :=  0.024433616717

  !KQ30 := -0.026641194737 !for alpha=0 at EFOC2
  !KQ38 :=  0.019316535913

  !KQ30 := -0.026277669054 !for r12=r34=0 from PR10 to EFOC2
  !KQ38 :=  0.019139729274

  PR10 : MARKER

  D105b : DRIF, L=1.82357
  D105a : DRIF, L=D105[L]-D105b[L]

  EFOC  : MARKER
  EFOC2 : MARKER

  D126d  : DRIF, L=385.0-351.0
  D126e  : DRIF, L=387.7240980-385.0
  D126cF : DRIF, L=D126c[L]-D126d[L]-D126e[L]

  LD126F : LINE=(D126a,ESAW,D126b,PVOT,D126cF,EFOC,D126d,EFOC2,D126e)

  ALINE : LINE=(&
    D101,ROLL1,B1A,B1B,D102,B2A,B2B,D103,ROLL2,&
    D104,Q10,Q10,D105a,PR10,D105b,Q11,Q11,D106,&
    BEGB,BA,D107,BA,D108,BA,D109,BA,D110,BA,D111,BA,&
    D112,Q19,Q19,D113,Q20,Q20,D114,&
    BA,D115,BA,D116,BA,D117,BA,D118,BA,D119,BA,ENDB,&
    D120,Q27,Q27,D121,"SQ27.5","SQ27.5",D122,Q28,Q28,&
    D123,Q30,Q30,D124,Q38,Q38,D125,WALL,&
    LD126F,ESAE,D127,BMDE)

! ------------------------------------------------------------------------------
! With the end point at EFOC

  ALINEF : LINE=(&
    D101,ROLL1,B1A,B1B,D102,B2A,B2B,D103,ROLL2,&
    D104,Q10,Q10,D105a,PR10,D105b,Q11,Q11,D106,&
    BEGB,BA,D107,BA,D108,BA,D109,BA,D110,BA,D111,BA,&
    D112,Q19,Q19,D113,Q20,Q20,D114,&
    BA,D115,BA,D116,BA,D117,BA,D118,BA,D119,BA,ENDB,&
    D120,Q27,Q27,D121,"SQ27.5","SQ27.5",D122,Q28,Q28,&
    D123,Q30,Q30,D124,Q38,Q38,D125,WALL,&
    D126a,ESAW,D126b,PVOT,D126cF,EFOC)

  S100EFOC : LINE=(S100,D002c,Q2,Q2,D003,Q3,Q3,D004,MK14,&
                   "50B1",D005,SWIVEL,ALINEF)

! ------------------------------------------------------------------------------

  RETURN